TeraTermマクロの多分完成
11.Feb.'19更新
TeraTermのマクロ(最下部)と作成上知った事
　先のマクロでは①マクロの中の時刻の間違いがあったのと、感度の設定をISO100(ダイヤモンドリング連写中)とISO500(多段階露光中)に設定することとしました。
　マクロと感度変更用ソフトはNkdPTP.dllとType0017.md3とともに1つのフォルダの中に入れておけばマクロ実行時にディレクトリを設定しなくても実行してくれます。
　一応臨機応変に対応するため!?に、いくつか近い感度のソフトも作っておきました。フォルダの中はこんな感じになっています
ここでの最大の問題…
　PCと接続中にはライブビューが使えず、SDKで制御できるか不明&Camera Contrl Pro2に背面のLV相当のスイッチ無しで使えない…

ちなみに
2019.02.11最新版マクロ⇒D.L.
;=====================================
;コマンドの指定
;=====================================
PIC3_Start = 'A'
PIC2_Int = 'B'
PIC2_Cont = 'C'
PIC1_Start = 'D'
Cont_C2 = 'E'
Cont_C3 = 'F'
Speed_Down_Capture = 'G'
Speed_Up_Capture = 'H'
Filter_Open = 'I'
Filter_Close = 'J'
Speed_Up = 'K'

;=====================================
;イベントの時刻
;=====================================
C1h = 15
C1m = 23
C1s = 3
C2h = 16
C2m = 38
C2s = 25
Maxh = 16 ;食の最大時
Maxm = 39 ;食の最大分
Maxs = 36 ;食の最大秒
C3h = 16
C3m = 40
C3s = 46
C4h = 17
C4m = 46
C4s = 40

;======================================
;イベント時刻の秒数化
;======================================
C1 = C1h*3600+C1m*60+C1s
C2 = C2h*3600+C2m*60+C2s
Max = Maxh*3600+Maxm*60+Maxs
C3 = C3h*3600+C3m*60+C3s
C4 = C4h*3600+C4m*60+C4s

;======================================
;自動撮像プログラム部分
;======================================
NowTime = 0
a=0

while a=0
Call Time_Now
if ((Max-NowTime)%60 = 0) then
dispstr ' 全景撮像開始 :'
send PIC3_Start
break
endif
endwhile

while a=0
Call Time_Now
if (Max-NowTime = 300) then
dispstr ' クライマックス10秒間隔開始 :'
send PIC2_Int
break
endif
endwhile

while a=0
Call Time_Now
if (C2-NowTime = 15) then
dispstr ' フィルター開 :'
send Filter_Open
wait 'I'

dispstr ' クライマックス連写開始 :'
send PIC2_Cont
wait 'C'

dispstr ' C2 ダイヤモンドリング撮像開始 :'
send Cont_C2
wait 'E'
break
endif
endwhile

dispstr ' ISO500変更　　'
exec 'ISO500.exe'
pause 3

dispstr ' 偏光撮像開始 :'
send PIC1_Start
wait 'D'

dispstr ' コロナ多段階撮像開始 :'
while a = 0
send Speed_Down_Capture
wait 'G'
call Time_Now
if C3 - NowTime <= 20 then
send Speed_Up
dispstr ' 最高速度化 :'
wait 'K'
break
endif

send Speed_Up_Capture
wait 'H'
call Time_Now
if C3 - NowTime <= 18 then
break
endif
endwhile

dispstr ' ISO100変更　　'
exec 'ISO100.exe'
pause 3

dispstr ' C3 ダイヤモンドリング撮像開始 :'
send Cont_C3
wait 'F'

dispstr ' クライマックス10秒間隔開始:'
send PIC2_Int
wait 'B'

dispstr ' フィルター閉 :'
send Filter_Close
wait 'J'

end

;==============
;現在時刻を取得する
;==============
:Time_Now
gettime hour '%H'
gettime mini '%M'
gettime seco '%S'
str2int Nowh hour
message = Nowh
str2int Nowm mini
str2int Nows seco
NowTime = Nowh*3600+Nowm*60+Nows
return
inserted by FC2 system